Előfordul a Mac használata során, hogy olyan tartalmakkal találkozunk, amelyek létrehozási dátuma valamilyen okból nem valós. Ennek számos oka lehet: hibásan rögzíti egy kamera, hálózati tárolóra másoljuk, majd onnan a letöltéskor valamiért a létrehozási idő helyett a letöltés ideje lesz a keletkeztetés dátuma, vagy éppen egy hosszú videófelvételből a QuickTime segítségével kivágunk egy részletet, és a részlet létrehozási ideje nem örökli a forrás létrehozási idejét.
A fájl létrehozási dátum módosításának feladatkörére az Automator program segítségével létrehozhatunk egy egyszerű funkciót, amelyet beépítve a Finder környezet megfelelő menüjébe célirányos megoldást kapunk erre a típusú kihívásra. A funkció során AppleScript szövegrészt használunk fel, kiaknázva a macOS ezen kitűnő képességét is!
Az Applications / Alkalmazások mappában található Automator programot elindítva a fogaskerék ikonnal jelölt Quick Action / Gyors művelet opciót kell választanunk.
Itt a legfelső részen egy beállítási menüsor található, ahol meg kell határoznunk, hogy melyik program mivel végezze el a műveletet. Esetünkben a Worflow receives current / A munkafolyanat az aktuálisat fogadja felnyíló menüből a files or folders / fájlok vagy mappák elemet kell választani, hiszen a funkció úgy működik majd, hogy egyszerű egy egérkattintással kiválasztjuk az átdátumozni kívánt fájlt (vagy akár mappát).
Az in / hely felirat melletti menüből a Finder alkalmazást kell választanunk, hiszen ott érintkezünk a fájlokkal és mappákkal. (Más beállítás e felületen nem szükséges.)
A Quick Action / Gyors művelet folytatása esetünkben egy AppleScript, amelynek lefuttatásával történik meg a dátum módosító művelet. Ehhez az ablak bal felén lévő listából a Run AppleScript / AppleScript futtatása parancsot kell kikeresnünk, és azt az ablak üres jobb oldalára húzni. Így az ablak alsóbb szekciója fogadni képes az AppleScript szövegét, amely révén rögtön gépelhetjük is az idevágó programkódot.
Az egyszerűség kedvéért ez az ilyen cikkeknél megszokott módon Courier betűtípussal a következő bekezdésben megtalálható (az alert és dialog részek ízlés szerint magyaríthatóak):
on run {input, parameters}
if input is {} then
display alert "No Finder items selected." buttons {"OK"} default button "OK"
return input
end if
set userInput to text returned of (display dialog ¬
"Enter the new creation date and time in this format:" & return & ¬
"YYYY-MM-DD HH:MM:SS" default answer "2026-04-02 12:00:00")
try
set setFileDate to do shell script "/bin/date -j -f '%Y-%m-%d %H:%M:%S' " & quoted form of userInput & " '+%m/%d/%Y %H:%M:%S'"
on error
display alert "Invalid date format." message "Please use: YYYY-MM-DD HH:MM:SS"
return input
end try
repeat with anItem in input
try
set posixPath to POSIX path of (anItem as alias)
do shell script "/usr/bin/SetFile -d " & quoted form of setFileDate & " " & quoted form of posixPath
on error errMsg
display alert "Failed to update file" message errMsg
end try
end repeat
display dialog "Creation date updated for " & (count of input) & " item(s)." buttons {"OK"} default button "OK"
return input
end run
Mint a szkript szövegéből látszik, a gyors művelet ÉÉÉÉ-HH-NN ÓÓ:PP:MM formátumban kéri megadni az új dátumot és időpontot. Természetesen nem szükséges másodperc részletességgel megadnunk az idevágó információt, de órát és percet mindenképp hasznos adni, hogy ne pontban nulla órakor készüljön a felvétel.
Amennyiben videó fájlokról van szó, és a birokunkban van más kamerával rögzített, helyes időkóddal rendelkező felvétel is, amelyen egyértelműen azonosítható másodperc pontosan a rögzítés kezdetének időpontja (például jellegzetes hanghullám képi megjelenése, csapó csattanása, stb.), akkor azért érdemes a másodperc pontosságú idő megadására, hogy például a Final Cut Pro felületén lévő többkamerás szerkesztés (multicam edit) hatékonyabban működjön manuális beavatkozás nélkül. (Természetesen utólag is tudunk finomítani a Final Cut Pro felületén ezen.)
A mentés (Command ⌘ + S) révén egy párbeszédablak jelenik meg, ahol elnevezhetjük a gyors műveletet. Ez az a név lesz, amellyel a Finder megfelelő menüjében a parancs megjelenik.
A mentést követően a funkció be is kerül a Finder szolgáltatásai közé, vagyis a ~ (felhasználói fiók): Library : Services mappába, és a Finder másodlagos kattintásra (Control-kattintás, „jobb” egérgombbal kattintás, stb.) megjelenő környezetfüggő menüjének Quick Actions / Gyors műveletek almenüjében is.
A funkció használatához ki kell választanunk azt a fájlt, amelynek létrehozási dátuma nem megfelelő, és ezt követően a menüből behívni a Létrehozási dátum módosítása névvel illetett gyors műveletet.
Ekkor párbeszédablak jelenik meg, amelyben gépeléssel meg tudjuk adni a dátumot és időt a fentebb felvázolt részletességgel.
Megjegyzés: A dátum módosítása sikeresen lezajlik, de a Finder sok esetben nem frissül le akár órákig vagy napokig. Ha a Finder programot újraindítjuk, ez a frissülés azonnal lezajlik. A Finder újraindítására az egyik mód, hogy a Quit / Kilépés parancsot a Terminal használatával aktiváljuk a Finder programmenüjében is, hiszen ez onnan hiányzik:
defaults write com.apple.Finder QuitMenuItem -bool true; killall Finder
Ennek köszönhetően ki tudjuk léptetni a Finder programot, és újra elindítva az már a valós dátumot jelzi ki. (Fontos, hogy a kiléptetéssel a Time Machine mentés és másféle másolási műveletek megszakadnak, vagyis csak akkor léptessük ki a Findert, ha ilyen nincsen folyamatban.)
Újraindíthatjuk a Finder környezetet a Force Quit / Kilépésre kényszerítés ablakból is, amelyet az alma menüből érhetünk el, vagyis a Command + Option + Esc billentyűparanccsal, és ott a Finder elemet választva a Relaunch gomb jelenik meg. Ez azonnal újraindítja a Finder folyamatot, és a létrehozási dátum frissül.
© MacMag.hu | Cikk: Birincsik József 2026. április 7.
Keresés a lap tartalmában a Google motorja segítségével: